AmigaOS 1.3 'askL' & 'askM' commands

[malko]

Now that I found a way to use variable(s) inside a script, the next step was to find a way to get some "real" input from the user by allowing him/her to type an answer (like asking the source/destination/a name/etc. - and not only a yes/no tests as with the original 'ask' command).

Honestly speaking, it was not a "keep it easy" task and it shook my mind in a lot of directions.

Finally I came across a solution (my install is a WB 1.3.3 - other versions not tested). It is maybe not the most 'clean' idea but it does the job so ...

The working solution requires to create two scripts. The "main" script (I called it AskL for "ask long") that the user execute and another script, a "stealth"* one (AskL2) that is called by the first one to 'do the job' of retrieving the user input and storing the variable.
*see StingRay post #2

The 'command' ends when an answer is provided (otherwise it keeps asking).

Here are the codes :

AskL :
.key question
.bra {
.ket }
.def question "? "
lab mlk ;(see below)
echo "{question}" NOLINE
execute >NIL: AskL2 reponse ? ;>NIL: to switch the execute to 'non visible' 
                              ;      mode (stealth)
                              ;'?'   to force the 'template' mode (like when 
                              ;      you don't remember the arguments/options 
                              ;      of a command) and since it is invisible, we 
                              ;      don't see we have switched to another 
                              ;      command :p
if EXISTS t:repondu
   delete t:repondu QUIET
else
   ;skip mlk BACK ;not working. As I can see, the above 'execute' makes that
                  ;the script looses the labels he knows... Grrrr... :(
   execute AskL "{question}"
endif

AskL2 :
.key variable,a7_,b7_,c7_,d7_,e7_,f7_,g7_,h7_,i7_,j7_,k7_,l7_,m7_,n7_,o7_,p7_,q7_,r7_,s7_,t7_,u7_,v7_,w7_,x7_,y7_,z7_  ;adapt the amount of needed arguments (c.f. below)
.bra {
.ket }
;warning: At prompt, do not type the same value as the name of one of the
;         argument. It will hang the execute command and thus also the script.
if "{a7_}" EQ ""
   if EXISTS t:repondu
      delete t:repondu QUIET
   endif
else
   setenv {variable} "{a7_} {b7_} {c7_} {d7_} {e7_} {f7_} {g7_} {h7_} {i7_} {j7_} {k7_} {l7_} {m7_} {n7_} {o7_} {p7_} {q7_} {r7_} {s7_} {t7_} {u7_} {v7_} {w7_} {x7_} {y7_} {z7_}"  ;adapt to your needs (c.f. above)
   echo >t:repondu "" NOLINE
endif

Don't forget to

protect AskL +s

and now you can simply type

AskL
or
AskL "question ? "

Then the provided answer is available through the 'getenv' command

getenv reponse

and it can be used as described here : https://eab.abime.net/showthread.php...27#post1510227

Any comment is welcome.

[malko]

I didn't mention it in my previous post but the AskL scripts accept answer from 1 word to up to 26 words separated by spaces (or more if you adapt the second script - but 26 words is already a long phrase and thus is more than enough I think).

A much simpler solution, made of only 1 script, would consist of accepting a only 1 word answer OR require the user to put in quotes multiple words answer :

AskM :
.key question
.bra {
.ket }
.def question "? "
lab mlk
echo "{question}" NOLINE
failat 21
setenv >NIL: reponse ?   ;see 'AskL' for the comments regarding '>NIL:' & '?'
if ERROR
   skip mlk BACK
endif
if "$reponse" EQ ""
   skip mlk BACK
endif

As previously the provided answer is available through the 'getenv' command

getenv reponse

and it can be used as described here : https://eab.abime.net/showthread.php...27#post1510227

[malko]

Quickly tested the scripts AskL/AskL2 & AskM under WB 1.3.2 (34.28), 1.3 (34.21). They are also working fine.

In the other hand, WB 1.2 (33.56), 1.1 (31.334) and 1.0 (30), have no 'setenv', 'getenv' commands. Neither have them the NOLINE argument for the 'echo' command or the T: and ENV: by default. Therefore the scripts won't work as is.