ARexx help for a workbench menu action

[gulliver]

Hi, I have set a workbench menu item with Toolsdaemon, and I want it to open the current workbench selected file with c:ed. I know this can be done with an ARexx script, but I dont know how

I would really apreciate if someone could help me, as ARexx is chinese for me

[daxb]

That should be feasible with GETATTR command (have a look at ARexx.doc) if OS version ist 3.9 (or 3.5?). WINDOW.ICONS.SELECTED if you want to get selected icons.

I don`t know Toolsdaemon but maybe it has already a function that can parse selected files? Similar to DOpus its {f} for example. Would be the better solution.

[idrougge]

3.9 or earlier? In 3.9 you can do this without ToolsDaemon.

[Korodny]

Originally Posted by gulliver

Hi, I have set a workbench menu item with Toolsdaemon

With 3.9, you don't need Toolsdaemon anymore, you can add a menu item to the tools menu using simple ARexx scripts:

/* This script will add a menu item to the Workbench's "Tools" menu */

ADDRESS workbench
MENU ADD NAME '"<SOME_INTERNAL_REFERRER>"' TITLE '"<TITLE_THAT_APPEARS_IN_MENU>"' CMD "<COMMAND_TO_EXECUTE>"

The text in angled brackets needs replacing with your own values, obviously, and you can add as menu "MENU ADD..." lines to the above script as you want, then create an icon for it and put it in WBStartup.

and I want it to open the current workbench selected file with c:ed. I know this can be done with an ARexx script, but I dont know how

The following is completely untested, as I don't have a 3.9 setup to test right now. Maybe some of the people who do and have have some ARexx experience can help debugging this - experience tells me it won't work out of the box

/* not tested at all */

options results
address "WORKBENCH"

getattr windows.active
ActiveWin = result

getattr window.icons.selected name ActiveWin stem ActiveWinIcons

SourceFile = ActiveWin
if right(SourceFile,1) ~= ":" then SourceFile = SourceFile || "/"
SourceFile = SourceFile || ActiveWinIcons.0.name

address command 'C:ed "'SourceFile'"'

No error checking at all, it simply tries to open the first selected file (and only that) with C:ed.

[gulliver]

@Korodny

Thank you very much, the script works beautifully!

It does not check for errors, but certainly works

@daxb

I now have an easy working example from which I can start learning ARexx little by little.

Thanks

@idrougge

On 3.9 I use T.H.E. instead of ToolsDaemon

[Minuous]

BB4 actually has something similar already ("Tools|Edit text file..." command), the main difference being that it asks for a filename (via ASL). Maybe I should change this so that it automatically operates on the selected file.

[gulliver]

Originally Posted by Minuous

BB4 actually has something similar already ("Tools|Edit text file..." command), the main difference being that it asks for a filename (via ASL). Maybe I should change this so that it automatically operates on the selected file.

Yes, I just checked. To tell you the truth it is better this way (and it works just as it is), but I would only add to it, the missing error handling.

[Minuous]

Here's a new version of the above script that will just open with a blank file if nothing is selected.

/* "Tools|Edit Text File..." command */

OPTIONS RESULTS
ADDRESS "WORKBENCH"

GETATTR WINDOWS.ACTIVE
SourceFile = RESULT
IF SourceFile = "" THEN DO
    ADDRESS COMMAND 'SYS:Tools/EditPad'
    EXIT
END

GETATTR WINDOW.ICONS.SELECTED.COUNT NAME SourceFile
IF RESULT = 0 THEN DO
    ADDRESS COMMAND 'SYS:Tools/EditPad'
    EXIT
END

GETATTR WINDOW.ICONS.SELECTED NAME SourceFile STEM ActiveWinIcons
IF RIGHT(SourceFile,1) ~= ":" THEN SourceFile = SourceFile || "/"
SourceFile = SourceFile || ActiveWinIcons.0.NAME
ADDRESS COMMAND 'SYS:Tools/EditPad "'SourceFile'"'

[fgh]

Originally Posted by Minuous

Here's a new version of the above script that will just open with a blank file if nothing is selected.

/* "Tools|Edit Text File..." command */

OPTIONS RESULTS
ADDRESS "WORKBENCH"

GETATTR WINDOWS.ACTIVE
SourceFile = RESULT
IF SourceFile = "" THEN DO
    ADDRESS COMMAND 'SYS:Tools/EditPad'
    EXIT
END

GETATTR WINDOW.ICONS.SELECTED.COUNT NAME SourceFile
IF RESULT = 0 THEN DO
    ADDRESS COMMAND 'SYS:Tools/EditPad'
    EXIT
END

GETATTR WINDOW.ICONS.SELECTED NAME SourceFile STEM ActiveWinIcons
IF RIGHT(SourceFile,1) ~= ":" THEN SourceFile = SourceFile || "/"
SourceFile = SourceFile || ActiveWinIcons.0.NAME
ADDRESS COMMAND 'SYS:Tools/EditPad "'SourceFile'"'

Hey there. It's been a few years, but I see you're still active here..

Just found this script of yours and started using it with MenuTools for textedit and multiview on my new 3.2.2.1 install.
It works great!

The only tiny issue is with multiview. If multiview is started without any flile selected and multiview is then closed without selecting a file, the script throws the DOS message that multiview failed with returncode 20.

I added Options failat 21, and the arexx part of the error message went away (showing line numbers etc) but there is still a popup window with the dos error message which does not appear if I do the same manually from shell. (Open multiview then quit without choosing a file)

Any ideas how to ignore the returncode from multiview entirely?

Anyway - a very useful script. Thanks!

[KONEY]

Glad this post surfaced because I was not aware of the menu function and it's great!

However, I cannot get an AmigaDOS executable to be started by a menu entry. I tried some combination of these:

PHP Code:

CMD "ADDRESS COMMAND 'work:utils/ced'" 


with no luck. Is it possible, at all?

Thanks!

[Minuous]

It works here if I use:

ADDRESS COMMAND 'work:utils/ced'

[KONEY]

Thanks, you mean like this?

PHP Code:

MENU ADD NAME CED TITLE "CED" ADDRESS COMMAND "work:utils/ced" 


...which is not working for me. Menu entry appears but program is not executed and SnoopDOS says this:

PHP Code:

Count Process Name          Action  Target Name                 Options Res.
----- ------------          ------  -----------                 ------- ----
1     Workbench Rexx Handle ChangeD Ram Disk:                               
2     Workbench Rexx Handle Open    CON:0/10/568/124/Output win Write   OK  
3     Workbench Rexx Handle Open    CONSOLE:                    Write   OK  
4     ARexx                 Open    *                           Write   OK  
5     Workbench Rexx Handle ChangeD SYS: