Best Way to Convert 32-bit Signed Value to 16 Bit?

[AGS]

Hi,

I need an optimisation for this:

; convert d0 from 32 to 16 bit

        move.l    #$7fff,d1
        cmp.l    d1,d0
        blt    .low_d0
        move.w    d1,d0
        bra    .ready
.low_d0        cmp.l    #$ffff8000,d0
        bgt    .ready
        move.w    #$8000,d0
.ready

I guess it converts a SIGNED 32 bit value (comes in d0) into a 16 bit value into d0. Is there a better way to do this? The problem is, values greater than $7fff should become $7fff and values smaller than $8000 should become $8000. Right?

ags

[Thorham]

You want signed 32 bit to signed 16 bit conversion with clamping, right?

[AGS]

I guess yes, what is clamping?

[Thorham]

Originally Posted by AGS

what is clamping?

It's simply setting a variable to a maximum if the variable is larger than that maximum, or setting it to a minimum if the variable is smaller than that minimum (or both). For example, if A=300 and the maximum is 255, then A is set to 255.

[AGS]

Yes, thats what I want.

[Thorham]

Then you could do it like this, although it's not really optimized, only the program flow is improved:

    move.l  #$7fff,d1
    cmp.l   d1,d0
    bgt     .l1

    move.l  #$ffff8000,d1
    cmp.l   d1,d0
    blt     .l1

    move.w  d0,d1
.l1
    move.w  d1,d0

Having to clamp two ways always sucks. For one way clamping to 255 or 0 you can do it in two instructions, I think. For two way byte clamping you can use a table.

I'm curious to see if anyone can come up with anything optimized for this.

[thomas]

How about this:

	tst.l	d0
	bmi	.minus

	tst.w	d0
	bpl	.ok

	move.w	#$7fff,d0
	bra	.ok

.minus
	tst.w	d0
	bmi	.ok

	move.w 	#$8000,d0

.ok

[AGS]

Looks good!

[Thorham]

To thomas:

You made a mistake.

[Leffmann]

    move.l  #-$8000, d1
    cmp.l   d1, d0
    blt     .1

    not.l   d1
    cmp.l   d1, d0
    ble     .2

.1  move.w  d1, d0
.2

[AGS]

Impressive!

[Thorham]

Nice

[pandy71]

Originally Posted by Thorham

You want signed 32 bit to signed 16 bit conversion with clamping, right?

Technically correct is http://en.wikipedia.org/wiki/Saturation_arithmetic

[Don_Adan]

Perhaps the fastest version is version based on meynaf's trick.

 move.w D0,A0
 cmp.l D0,A0
 beq.b OK
 move.w #$8000,D0
 tst.l D0
 bmi.b OK
 not.w D0
OK

[AGS]

I am impressed that this part of code of mine could really be optimized so good. I thought of solutions, but did not get the answer alone. Don, your Trick is faster as it only moves a word number instead of a long, and does this only when necessary. The previous solution did this always. What is actually "Meynaf's TRick"? What happens when you move a .w into an address register?

[Thorham]

I think it's this:

; to see if a value is between $FFFF8000 and $7FFF, better put it in An reg :
 cmpa.w a0,a0  ; cmp with a0.w extended to .l, and a0.l

[AGS]

Hmm, looks interesting but you lost me. Please try again.

[Thorham]

The trick is based on the fact that when you move a word value into an address register it's automatically sign extended to a long word. For the rest I haven't figured it out, either

[AGS]

AH, ok, now i understand.

[Don_Adan]

Originally Posted by AGS

I am impressed that this part of code of mine could really be optimized so good. I thought of solutions, but did not get the answer alone. Don, your Trick is faster as it only moves a word number instead of a long, and does this only when necessary. The previous solution did this always. What is actually "Meynaf's TRick"? What happens when you move a .w into an address register?

This is not my idea, but meynaf's (french coder, available on EAB too) trick, he used this trick in own productions for fast range check (-32768 to +32767). Moving word into address register works as move.w and ext.l together.