Help needed!!Random octal numbers generator(asm)

I need help in displaying a random 8 digit octal number on the seven segments using 68k assembly language.
I'm designing a software of reaction timer but the first problem come to me is in generating random octal number.
Your help is highly appreciated.

[Leffmann]

Do you mean that you want to generate 8 random digits of base 8?

Randomize   lea         State(pc), a0
            lea         Digits(pc), a1
            move.l      (a0), d0
            moveq       #8-1, d2

loop        ; generate a random value

            move.l      d0, d1
            lsl.l       #2, d1
            eor.l       d1, d0
            move.l      d0, d1
            lsr.l       #7, d1
            eor.l       d1, d0
            move.l      d0, d1
            lsl.l       #7, d1
            eor.l       d1, d0

            ; extract a base 8 digit and store as one byte

            moveq       #7, d1
            and.b       d0, d1
            move.b      d1, (a1, d2.w)
            
            dbf         d2, loop

            move.l      d0, (a0)
            rts

            ; initialize this 32-bit value to non 0 when program starts

State       ds.l        1

            ; Digits will contain 8 bytes, each being a number from 0 to 7

Digits      ds.b        8

[Thorham]

Originally Posted by sheryn88

I need help in displaying a random 8 digit octal number on the seven segments using 68k assembly language.
I'm designing a software of reaction timer but the first problem come to me is in generating random octal number.
Your help is highly appreciated.

You can try this code. It's by no means the best, but it's simple and it should work nicely.

start
	bsr	rng
	rts
	
rng
	lea	digits,a0
	move.l	#$11111111,d0
	move.l	state,d1
	moveq	#0,d2
	moveq	#7,d6

	moveq	#7-1,d7		;Number of digits-1.
.loop
	add.l	d0,d2
	rol.l	#7,d1
	add.l	d2,d1

	move.l	d1,d3
	and.l	d6,d3		;Need ascii? Add ascii value of "0" to d3.
	move.b	d3,(a0)+
.next
	dbra	d7,.loop
	
	move.l	d1,state
	rts

state
	dc.l	$52896594	;Seed value. Set to anything.
digits
	dc.b	7
	even

Originally Posted by Leffmann

            move.l      d0, d1
            lsl.l       #2, d1
            eor.l       d1, d0
            move.l      d0, d1
            lsr.l       #7, d1
            eor.l       d1, d0
            move.l      d0, d1
            lsl.l       #7, d1
            eor.l       d1, d0

You may want to look at your shift values, they don't seem to be chosen well. I've tested it by plotting points based on x,y cords obtained from this generator, and it's patterned.

[Leffmann]

Hm I did the same test just now and it looks perfectly uniform, and it also passed almost all tests in the Diehard test suite. But let's keep the random-insanity in the other thread, I think sheryn88 was just looking for something simple to test his 7-segment display with.

Thanks!!! But i found that the random numbers generated are actually uniform. The group of numbers generated each time i run the program are actually the same. Is it ought to be uniform like this?

[Thorham]

Originally Posted by sheryn88

Thanks!!! But i found that the random numbers generated are actually uniform. The group of numbers generated each time i run the program are actually the same. Is it ought to be uniform like this?

It's supposed to be like this. Each time you run the program it starts with the same state or seed, and therefore the numbers will be the same each time, but it's quite simple to fix:

start
	bsr	randomize
	bsr	rng
	rts

randomize
	lea	$bfe001,a0

	add.b	$400(a0),d0
	lsl.l	#4,d0
	add.b	$500(a0),d0
	lsl.l	#4,d0
	add.b	$600(a0),d0
	lsl.l	#4,d0
	add.b	$700(a0),d0
	move.l	d0,state
	
	rts
	
rng
	lea	digits,a0
	move.l	#$11111111,d0
	move.l	state,d1
	moveq	#0,d2
	moveq	#7,d6

	moveq	#7-1,d7		;Number of digits-1.
.loop
	add.l	d0,d2
	rol.l	#7,d1
	add.l	d2,d1

	move.l	d1,d3
	and.l	d6,d3		;Need ascii? Add ascii value of "0" to d3.
	move.b	d3,(a0)+
.next
	dbra	d7,.loop
	
	move.l	d1,state
	rts

state
	dc.l	0
digits
	dc.b	7
	even

I've added a seed randomizing routine to the code, and it should now produce new numbers each time the program is run (although the seeding algorithm probably isn't the best).

Thanks a lot for the help!!!