Timer instantly causes interrupt

[TCH]

I have this code:

		move.b		#$0c,$BFDE00		; Stop Timer A.
		move.b		#$7f,$BFDD00		; Disable all CIA interrupts.
		move.w		#$2000,$DFF09A		; Disable L6 interrupts.
		move.l		#$7ff00,$78		; L6 interrupt now points to the copied code.
		move.w		#$a000,$DFF09A		; Enable L6 interrupts.
		move.b		#$81,$BFDD00		; Enable Timer A interrupt.
		move.b		#$00,$BFD400
		move.b		#$60,$BFD500		; Load $6000 into Timer A and start.

It does not wait until underflow, it causes an interrupt instantly. What i am doing wrong?

[a/b]

1. set $dff09a to $2000 first (what if L6 int occurs between $bfdd00/e00 and $dff09a? doesn't necessarily have to timer a), this way you also don't have to stop the timer
2. clear L6 bit in INTREQ ($dff09c) before you re-enable interrupts in case it's been set already
3. you start the timer a by writing $11 (continuous) or $19 (one-shot) to $bfde00, not by setting the initial count, at the end

[TCH]

1., 2.: Okay, i did so and this way it never fires.
3. Manual says otherwise, but okay, i did so and this way it instantly fires again.

		move.w		#$2000,$DFF09A		; Disable L6 interrupts.
		move.b		#$7f,$BFDD00		; Disable all CIA interrupts.
		move.l		#$7ff00,$78		; L6 interrupt now points to the copied code.
		move.w		#$2000,$dff01e		; Clear L6 interrupt request.
		move.w		#$a000,$DFF09A		; Enable L6 interrupts.
		move.b		#$81,$BFDD00		; Enable Timer A interrupt.
		move.b		#$00,$BFD400
		move.b		#$60,$BFD500		; Load $6000 into Timer A.
		move.b		#$19,$BFDE00		; Start Timer A.

[ross]

This is the proper way:

		move.w		#$2000,$DFF09A		; Disable L6 interrupts.
		move.b		#$7f,$BFDD00		; Disable all CIA interrupts.
		move.b		#8,$BFDE00		; Stop timer, One-Shot mode
		tst.b		$BFDD00			; Clear pending
		move.w		#$2000,$dff09C		; Clear L6 interrupt request.
		move.l		#$7ff00,$78		; L6 interrupt now points to the copied code.
		move.b		#$81,$BFDD00		; Enable Timer A interrupt.
		move.b		#$00,$BFD400
		move.b		#$60,$BFD500		; Start Timer A.
		move.w		#$a000,$DFF09A		; Enable L6 interrupts.

EDIT: stop timer in the right position

[a/b]

$dff01e is INTREQR (read only), to write a value you have to use $dff09c.

This works for me (assumes VBR=0):

	lea	($bfd000),a0
	lea	($dff000),a6
	move.l	($78).w,d0

	move.w	#$2000,($09a,a6)	; int6 off
	move.b	#$7f,($d00,a0)		; all ints off
	move.b	#$10,($e00,a0)		; stop timer a
	move.l	#int6,($78).w
	move.w	#$2000,($09c,a6)	; clear int6 req
	move.w	#$e000,($09a,a6)	; master+int6 on
	move.b	#$81,($d00,a0)		; timer a int on
	move.b	#$00,($400,a0)		; timer a low
	move.b	#$60,($500,a0)		; timer a high
	move.b	#$11,($e00,a0)		; timer a: force, continuous, start

Wait	btst	#6,($e001-$d000,a0)	; wait lmb
	bne.b	Wait

	move.b	#$10,($e00,a0)		; stop timer a
	move.l	d0,($78).w
	rts

int6	tst.b	($bfdd00)		; ack timer a int
	move.w	#$2000,($dff09c)	; clear int6 req
	move.w	#$fff,($dff180)
	move.w	#$000,($dff180)
	rte

[TCH]

@ross: Thank you, that worked.

@a/b: Thanks, but in the meantime it has been solved.

[hooverphonique]

Originally Posted by TCH

@a/b: Thanks, but in the meantime it has been solved.

Maybe, but it's still important that you understand what a/b tried to tell you.
All the custom chip registers are read- or write-only, and you need to distinguish between them

[ross]

Originally Posted by hooverphonique

Maybe, but it's still important that you understand what a/b tried to tell you.
All the custom chip registers are read- or write-only, and you need to distinguish between them

And add to this that usually CIA registers are with separate functions for reading and writing..

[TCH]

Ah, i see now, sorry. The code was partly copied and i must have confused

INTREQR

with

INTREQ

, hence the swapping of

move.w #$2000,$dff09c

with

move.w #$2000,$dff01e

. (I was aware of them being unidirectional.) Thanks for the correction guys.