Filling with the blitter...

[Lonewolf10]

Hi,

I'm trying to fill an area of the screen, but it doesn't seem to be working. I'm probably doing something stupid (so feel free to point it out! ), but can't seem to spot it

I did try searching online for some example code, but all I could find were lots of pages from the Amiga HRM - I already have the real thing.


Here's my code...

    lea.l    screen+572+8000,a0    ;destination
    move.w    #26,d0            ;modulo, was #28
    move.w    #$2D87,d1        ;BLTSIZE, hhhhhhhhhhwwwwww
                    ;         0001100100000111
                    ;TEMP:      0010110110000111=$2B87
                    ;      width=7 words,
                    ;      height=100 lines
                    ;set to $1907 after debugging done
                    ;$2D87 is perfection! ;)
    jsr    fillscreen
    rts

fillscreen:
        ;- descending mode must be used
        ;- set inclusive (bit #3) or exclusive (bit #4) in BLTCON1
        ;- set bit #2 of BLTCON1 to fill area outside of lines

    btst    #6,DMACONR        ;safety check
.waitblit
    btst    #6,DMACONR        ;blitter ready?
    bne    .waitblit
    move.l    a0,BLTDPTH        ;a0=destination address and source
    move.l    a0,BLTCPTH
    move.w    d0,BLTDMOD        ;d0=modulo (e.g. 36 for lowres)
*    clr.w    BLTCON1            ;d1=size of area, in BLTSIZE format
    bset    #1,BLTCON1        ;descending mode
    bset    #2,BLTCON1        ;fill carry input
    bset    #3,BLTCON1        ;inclusive fill enable
    move.w    #$0301,BLTCON0        ;use D & C, LF=2 (not A&B)
*    move.w    #$FFFF,BLTAFWM
*    move.w    #$FFFF,BLTALWM
    move.w    d1,BLTSIZE
    rts

Once working I will remove the bset's and combine them into a move.w


Regards,
Lonewolf10

[victim]

Hi Lonewolf10,

in your fill mode combination, you don't need the modulo value
In this case, it is simply cleared and your BLTCON1 was not correct set.

try this code for filling one bitplane with the size 320*256

Fill:
        btst.b    #6,$dff002
FillIn: 
        btst.b    #6,$dff002
        bne.s     FillIn
        move.l    PlaneBufferWork(pc),a0
        lea.l       256*40(a0),a0
        move.l    #0,$dff064        ;clear modulo A and D
        move     #%0000100111110000,$dff040    ;boolean minterms
        move     #%0000000000010010,$dff042    ;descending and fill mode
        move.l    a0,$dff050        ;source A
        move.l    a0,$dff054        ;destination    D
        move     #256*64+20,$dff058
        rts

PlaneBufferWork:     dc.l    Buffer1
Buffer1:                  blk.b    320*256/8,0

Regards,
victim

Originally Posted by Lonewolf10

Hi,

I'm trying to fill an area of the screen, but it doesn't seem to be working. I'm probably doing something stupid (so feel free to point it out! ), but can't seem to spot it

I did try searching online for some example code, but all I could find were lots of pages from the Amiga HRM - I already have the real thing.


Here's my code...

    lea.l    screen+572+8000,a0    ;destination
    move.w    #26,d0            ;modulo, was #28
    move.w    #$2D87,d1        ;BLTSIZE, hhhhhhhhhhwwwwww
                    ;         0001100100000111
                    ;TEMP:      0010110110000111=$2B87
                    ;      width=7 words,
                    ;      height=100 lines
                    ;set to $1907 after debugging done
                    ;$2D87 is perfection! ;)
    jsr    fillscreen
    rts

fillscreen:
        ;- descending mode must be used
        ;- set inclusive (bit #3) or exclusive (bit #4) in BLTCON1
        ;- set bit #2 of BLTCON1 to fill area outside of lines

    btst    #6,DMACONR        ;safety check
.waitblit
    btst    #6,DMACONR        ;blitter ready?
    bne    .waitblit
    move.l    a0,BLTDPTH        ;a0=destination address and source
    move.l    a0,BLTCPTH
    move.w    d0,BLTDMOD        ;d0=modulo (e.g. 36 for lowres)
*    clr.w    BLTCON1            ;d1=size of area, in BLTSIZE format
    bset    #1,BLTCON1        ;descending mode
    bset    #2,BLTCON1        ;fill carry input
    bset    #3,BLTCON1        ;inclusive fill enable
    move.w    #$0301,BLTCON0        ;use D & C, LF=2 (not A&B)
*    move.w    #$FFFF,BLTAFWM
*    move.w    #$FFFF,BLTALWM
    move.w    d1,BLTSIZE
    rts

Once working I will remove the bset's and combine them into a move.w


Regards,
Lonewolf10

[Toni Wilen]

Two problems. Quick hints:
1) bset reads before writing.
2) data size is not a word.

[Lonewolf10]

Thanks for the help guys, it's working now


Regards,
Lonewolf10

[Photon]

Know your Miniterns

[Lonewolf10]

Originally Posted by Photon

Know your Miniterns

Regards,
Lonewolf10

[victim]

Mistakes are often the best teachers.

One man's meat is another man's poison.

Originally Posted by Photon

Know your Miniterns

[phx]

Originally Posted by Toni Wilen

Two problems. Quick hints:
1) bset reads before writing.

Apropos, also be careful with CLR, which reads before it writes on the 68000. IIRC this was fixed with the 68010.