Fast switch statement code

[Jobbo]

I've found the need to write what is essentially a switch case.


Is there a better approach than the one I've got below?

Or is there a cleaner way to specify the same code?

    ; d1 = value to switch on

    add.w    d1,d1
    move.w    (.switch,pc,d1.w),d1
    jmp    (.case0,pc,d1.w)

.switch:
    .dc.w    .case0-.case0,.case1-.case0,.case2-.case0,.case3-.case0
    .dc.w    .case4-.case0,.case5-.case0,...

.case0:
    ; some code
    bra.s    .end
.case1:
    ; some different code
    bra.s    .end
.case2:
    ; some code
    bra.s    .end

    .
    .
    .
.end

[Thomas Richter]

That's pretty much the standard way, yes. Typically, it is also the best way. In case the "cases" are short and all pretty much the same size, you can also compute the target directly without going through a table:

lsl.w #3,d1
jmp cases(pc,d1.w)

where each entry (include the branch out of it) is 8 bytes.

Or, if you are calling this in a tight loop, pre-load an address register with the target of the case, and jump through the address register:

lsl.w #3,d1
lea cases(pc,d1.w),a0
....
;then, later
jmp (a0)

[a/b]

As Thomas mentioned, if the cases are short you can use equidistant entry points.
Otherwise, I typically go with (pre-scaled index if possible and) jmp (table,pc,rx.w) + bra.b|w or jmp xx(pc) to avoid unwanted bra.w to .b optimization, because bra and jmp xx(pc) are 10 cycles while move.w (xx,ax|pc,ry.w) is 14 cycles.

[meynaf]

Originally Posted by Jobbo

I've found the need to write what is essentially a switch case.

Is there a better approach than the one I've got below?

Or is there a cleaner way to specify the same code?

The best method depends on your goals.

You want it to be "clean", and not necessarily the fastest ?
Better not to mix data and code then, and thus you have to care about the extremely limited range of (pc,ix) addressing.
This gives :

 lea tbl(pc),a0
 add.w d1,d1
 adda.w (a0,d1.w),a0
 jmp (a0)

; moved after code
tbl
 dc.w case0-tbl,case1-tbl,case2-tbl,case3-tbl,...

You did not specify the cpu type, so bare 68000 is assumed.
But if you can run code on 68020+, then :

 lea tbl(pc),a0
 adda.w (a0,d1.w*2),a0
 jmp (a0)

tbl
 dc.w case0-tbl,case1-tbl,case2-tbl,case3-tbl,...

Otherwise if the goal is speed, the fastest method might depend on the number of cases and their relative frequency.

For example :

 subq.w #1,d1
 bcs.s .case0
 beq.s .case1
 subq.w #2,d1
 bcs.s .case2
 beq.s .case3
 subq.w #2,d1
 bcs.s .case4
 beq.s .case5
; .case6 here (if range is only 0-6)

If there are few cases, if .case0 is by far the most common, and then they have decreasing frequency, then this is the fastest method.

Else, it can be the usual pair of (pc,ix) or fixed size routines - as already mentioned.

Using direct 32-bit pointers might be faster than word table (not sure for 68000 but on 020+ it is). You can preload another register with the table address :

; this goes in init code
 lea tbl,a0

; normal code
 add.w d1,d1
 add.w d1,d1
 move.l (a0,d1.w),a1    ; on 020+, use (a0,d1.w*4)
 jmp (a1)

; table
 dc.l case0,case1,case2,case3,...

[JoeJoe]

I found the following interesting article:

[a/b]

68000 TRICKS AND TRAPS by Mike Morton, Byte Sep. 1986, pg. 170. Forgot about that, but as soon as I saw the picture you posted, light bulb lit up ;p.

[Don_Adan]

If you really want to reach maximum speed and your "cases" are not too long. You can handle all switch values not as 0,1,2,3... but as direct values f.e 0,8,16,24... or 0,16,32,48... or 0,32,64,96...
And later only one jump is necessary, but code must be correctly placed in your source/memory.

jmp case0(PC,D1.W)
case0
... (your code for case0)
ds.b (size of empty bytes to filling distance to next case routine for jump command)
case1

etc

[Jobbo]

Thanks everyone, I'll see if it's worth using the fixed size version.

Originally Posted by a/b

68000 TRICKS AND TRAPS by Mike Morton, Byte Sep. 1986, pg. 170. Forgot about that, but as soon as I saw the picture you posted, light bulb lit up ;p.

Does anyone have a collection of these tips somewhere? Or a good alternative read with lots of ideas.

[a/b]

That's the only one I have from the series, found a pdf somewhere on internet. I can upload it to the zone if you want to check it out (6 pages article).

[Jobbo]

I found it online myself.

[Don_Adan]

And of course if you have full control about input switches, you can use other linear values too f.e 0,20,40,60 ... or even totally non linear (for code without empty bytes between "cases") like 0, 14,36,48,56 ...