Reading the keyboard...

[DanScott]

Has anyone got a small, compact, fast & working (non system friendly) keyboard reading routine in ASM?

I can't seem to locate my old one on any of my (few) backups.

I seem to remember also a a sequence of NOP's in my original code (that I borrowed off Del)

[hooverphonique]

yeah, you need some delay for the handshake, so NOPs won't work with different cpu's..

[Asman]

You can use this one.

IntLvlTwoPorts:
		movem.l	d0-d1/a0-a2,-(a7)

		lea	_custom,a0
		moveq	#INTF_PORTS,d0

	;check if is it level 2 interrupt
		move.w	intreqr(a0),d1
		and.w	d0,d1
		beq.b	.end

	;check if SP cause interrupt, hopefully CIAICRF_SP = 8
		lea	_ciaa,a1 
		move.b	ciaicr(a1),d1
		and.b	d0,d1
		beq.b	.end

		move.b	ciasdr(a1),d1			;get keycode
		or.b	#CIACRAF_SPMODE,ciacra(a1)	;start SP handshaking

		lea	dt+keys(pc),a2
		not.b	d1
		lsr.b	#1,d1
		scc	(a2,d1.w)

	;handshake
		moveq	#3-1,d1
.wait1		move.b	vhposr(a0),d0
.wait2		cmp.b	vhposr(a0),d0
		beq.b	.wait2
		dbf	d1,.wait1

	;set input mode
		and.b	#~(CIACRAF_SPMODE),ciacra(a1)

.end		move.w	#INTF_PORTS,intreq(a0)
		tst.w	intreqr(a0)
		movem.l	(a7)+,d0-d1/a0-a2
		rte

Of course you need to set up PORTS ints. Instead of beam loop you can use cia, then wait will be more accurate. Example you can find in SolidGold source, which you can grab from aminet.
Or I can post above version with cia usage. Just give me a sign.

[dissident]

Originally Posted by Asman

You can use this one.

IntLvlTwoPorts:
		movem.l	d0-d1/a0-a2,-(a7)

		lea	_custom,a0
		moveq	#INTF_PORTS,d0

	;check if is it level 2 interrupt
		move.w	intreqr(a0),d1
		and.w	d0,d1
		beq.b	.end

	;check if SP cause interrupt, hopefully CIAICRF_SP = 8
		lea	_ciaa,a1 
		move.b	ciaicr(a1),d1
		and.b	d0,d1
		beq.b	.end

		move.b	ciasdr(a1),d1			;get keycode
		or.b	#CIACRAF_SPMODE,ciacra(a1)	;start SP handshaking

		lea	dt+keys(pc),a2
		not.b	d1
		lsr.b	#1,d1
		scc	(a2,d1.w)

	;handshake
		moveq	#3-1,d1
.wait1		move.b	vhposr(a0),d0
.wait2		cmp.b	vhposr(a0),d0
		beq.b	.wait2
		dbf	d1,.wait1

	;set input mode
		and.b	#~(CIACRAF_SPMODE),ciacra(a1)

.end		move.w	#INTF_PORTS,intreq(a0)
		tst.w	intreqr(a0)
		movem.l	(a7)+,d0-d1/a0-a2
		rte

You don't set the SP line for the pulse LOW then HIGH. Is this not necessary for the handshake as explaned in the HRM?

[ross]

Originally Posted by dissident

You don't set the SP line for the pulse LOW then HIGH. Is this not necessary for the handshake as explaned in the HRM?

This is basically unnecessary.
The bit is idle low and you are the only one setting and executing the pulse (and in any case completing the operation).

[dissident]

Originally Posted by ross

This is basically unnecessary.
Thx for your quick answer. The bit is idle low and you are the only one setting and executing the pulse (and in any case completing the operation).

Thx for your fast answer .That confirms my assumption that it seems not to be really necessary. Okay. so the only important thing seems to be the delay time for the handshake between setting input, then output. If I understood it correctly, 85 microseconds are not enough for some keyboards. 200 microseconds should be used instead for some keyboards.

[ross]

Originally Posted by dissident

..200 microseconds should be used instead for some keyboards.

Right
I usually use that value even if in fact is the keyboard that use delays outside the official specifications (probably too slow micros).