English Amiga Board


Go Back   English Amiga Board > Support > support.Games

 
 
Thread Tools
Old 21 March 2018, 13:49   #41
StingRay
move.l #$c0ff33,throat

StingRay's Avatar
 
Join Date: Dec 2005
Location: Berlin/Joymoney
Posts: 5,839
Quote:
Originally Posted by ross View Post
Well, using .w and the sign bit for accessMode is a great combo!
Bugs squared
For the bit of extra fun we all love.


I have updated the patch a bit, it should now run stable and also checks if it is already installed so running it twice is no problem (error code 10 is returned in that case).




Code:
; ViroCop Patch
; 
; patches Open() (dos.library) to accept accessMode as .w parameter
; this fixes the "Insert Disk 1" problem


START    move.l    $4.w,a6
    moveq    #0,d0            ; any version will do
    lea    DOSName(pc),a1
    jsr    -408(a6)        ; OpenLibrary()
    move.l    d0,a4
    tst.l    d0
    beq.b    .error

; patch Open() if patch is not installed
    lea    -30(a4),a0
    move.l    2(a0),a0
    cmp.l    #"STR!",2(a0)
    beq.b    .installed        ; patch is already installed

; allocate memory for patch code
    moveq    #Size,d0
    moveq    #0,d1            ; any memory will do
    jsr    -198(a6)        ; AllocMem()
    tst.l    d0
    beq.b    .error

    move.l    d0,a2

    moveq    #Size/2-1,d7
    move.l    d0,a1
    lea    NewOpen(pc),a0
.copy    move.w    (a0)+,(a1)+
    dbf    d7,.copy



    jsr    -132(a6)        ; Forbid()

    lea    -30.w,a0        ; Open()
    move.l    a4,a1            ; DOSBase
    move.l    a2,d0
    jsr    -420(a6)        ; SetFunction()
    move.l    d0,OldOpen-NewOpen(a2)

    jsr    -138(a6)        ; Permit()

.exit    moveq    #0,d0            ; no errors
    rts

.installed
    moveq    #10,d0            ; patch is already installed
    rts

.error    moveq    #20,d0            ; patch not installed
    rts



NewOpen    bra.b    .go
    dc.l    "STR!"
.go    swap    d2
    clr.w    d2
    swap    d2
    move.l    OldOpen(pc),-(a7)
    rts

OldOpen    dc.l    0

Size    = *-NewOpen

    dc.b    "$VER: Virocop patch 1.1 (21.03.2018) by StingRay/[S]carab^Scoopex",10,0
DOSName    dc.b    "dos.library",0
Attached Files
File Type: 68k ViroCopPatch.68k (240 Bytes, 10 views)
File Type: s ViroCop_Patch.s (1.2 KB, 4 views)
StingRay is offline  
AdSense AdSense  
Old 21 March 2018, 13:53   #42
dlfrsilver
CaptainM68K-SPS France
dlfrsilver's Avatar
 
Join Date: Dec 2004
Location: Melun nearby Paris/France
Age: 40
Posts: 7,373
Send a message via MSN to dlfrsilver
Thank you boys !
dlfrsilver is offline  
Old 21 March 2018, 14:22   #43
Seiya
Registered User

Seiya's Avatar
 
Join Date: Nov 2014
Location: Italy
Posts: 452
now it works!!
Thanks...
Seiya is offline  
Old 21 March 2018, 14:32   #44
StingRay
move.l #$c0ff33,throat

StingRay's Avatar
 
Join Date: Dec 2005
Location: Berlin/Joymoney
Posts: 5,839
Have fun. I'm almost tempted to create a "real" fix for this game, I'll see if I can be bothered (game is pretty good so it sure is worth it).
StingRay is offline  
Old 21 March 2018, 14:37   #45
Seiya
Registered User

Seiya's Avatar
 
Join Date: Nov 2014
Location: Italy
Posts: 452
Hired Guns i have solved using ipf, but cracked version is the same. after regolar installation i have red screeen and floppy drive that search floppy disk..
Seiya is offline  
Old 21 March 2018, 14:46   #46
AMIGASYSTEM
Registered User
AMIGASYSTEM's Avatar
 
Join Date: Aug 2014
Location: Brindisi (Italia)
Posts: 2,725
Quote:
Originally Posted by Seiya View Post
but don't work.

Assign ViroCop: ""
Assign ViroData1: ""
Assign ViroData2: ""
Askboot
Run >NIL: ViroCopPatch
ViroCopPal
AMIGASYSTEM is offline  
Old 21 March 2018, 14:52   #47
Seiya
Registered User

Seiya's Avatar
 
Join Date: Nov 2014
Location: Italy
Posts: 452
Quote:
Originally Posted by AMIGASYSTEM View Post
Run >NIL: ViroCopPatch
ViroCopPal
the first patch don't work. The latest one works perfectly
Seiya is offline  
Old 21 March 2018, 15:41   #48
AMIGASYSTEM
Registered User
AMIGASYSTEM's Avatar
 
Join Date: Aug 2014
Location: Brindisi (Italia)
Posts: 2,725
Yes, even the first one works even if sometimes it fails.

Thanks to StingRay
AMIGASYSTEM is offline  
Old 21 March 2018, 15:44   #49
StingRay
move.l #$c0ff33,throat

StingRay's Avatar
 
Join Date: Dec 2005
Location: Berlin/Joymoney
Posts: 5,839
Yeah, the output redirection to >NIL: is a good hint!
StingRay is offline  
Old 21 March 2018, 16:57   #50
Seiya
Registered User

Seiya's Avatar
 
Join Date: Nov 2014
Location: Italy
Posts: 452
but in my case, the first patch you released, i have failure on every commands and then crash the system with guru
Seiya is offline  
Old 21 March 2018, 21:41   #51
jotd
Cat freak
jotd's Avatar
 
Join Date: Dec 2004
Location: FRANCE
Age: 46
Posts: 2,115
don't run the patch in background. or you can have a race condition between the game & the patch. Well, that's theory. no need to run in background anyway.
jotd is offline  
Old 21 March 2018, 21:54   #52
Seiya
Registered User

Seiya's Avatar
 
Join Date: Nov 2014
Location: Italy
Posts: 452
however, now all works greatly
Seiya is offline  
Old 21 March 2018, 22:08   #53
StingRay
move.l #$c0ff33,throat

StingRay's Avatar
 
Join Date: Dec 2005
Location: Berlin/Joymoney
Posts: 5,839
The first version can indeed crash (coded before my first coffee, never a good idea) hence I updated the code and created a more stable version of the patch.
StingRay is offline  
Old 22 March 2018, 14:18   #54
Seiya
Registered User

Seiya's Avatar
 
Join Date: Nov 2014
Location: Italy
Posts: 452
and you have made a great fix
Seiya is offline  
AdSense AdSense  
 


Currently Active Users Viewing This Thread: 1 (0 members and 1 guests)
 
Thread Tools

Similar Threads
Thread Thread Starter Forum Replies Last Post
Virocop AGA WHDLoad Anakirob support.Games 22 19 March 2015 13:04
Worms DC AGA HD install Vollldo support.Games 7 18 March 2011 17:43
Error trying to install civ aga to HD dug26 support.WinUAE 2 07 June 2010 16:28
Mounting Native PC(formatted) harddisk as a Harddisk for WinUAE/E-UAE Zetr0 support.Hardware 10 01 June 2006 14:04
Ripping - Virocop AGA maVado project.Sprites 2 01 August 2005 21:42

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump


All times are GMT +2. The time now is 08:58.


Powered by vBulletin® Version 3.8.8 Beta 1
Copyright ©2000 - 2018, vBulletin Solutions, Inc.
Page generated in 0.32381 seconds with 13 queries