Updating part of a CopperList's palette? (DisplayLibrary)

[earok]

Is there a simple way of replacing a couple of colours on the Palette of a copper list, rather than replacing the entire Palette with DisplayPalette? (the colour-offset parameter in DisplayPalette seems to copy from an offset in the Palette, not an offset into the copper list)

[idrougge]

DisplayRGB Coplist#, Register, line, r, g, b, [copoffset]
CustomColors Coplist#, CCOffset, YPos, Palette, startcol, numcols, [thru256flag]

[earok]

Originally Posted by idrougge

DisplayRGB Coplist#, Register, line, r, g, b, [copoffset]
CustomColors Coplist#, CCOffset, YPos, Palette, startcol, numcols, [thru256flag]

Cheers.. I'm not using up any copper space currently so that's probably the easiest way to do things

[earok]

I ended up writing my own solution for what I wanted to do (replace colors 32-47 on an AGA copperlist, which I'm using for sprite colors). This is a very niche implementation, but I'm posting it here on the off chance it's of any help.

In brief, I have a "Sprite Palette" object for holding the 24 bit RGB values (split into upper and lower parts), which I fill with a regular Blitz palette object. I then paste that into the part of the copper list that sets colors 32-47

NEWTYPE .SpritePalette
	UpperRGB.w[16]
	LowerRGB.w[16]
End NEWTYPE

Statement FillSpritePalette{*SP.SpritePalette,PaletteIndex}
	PaletteInfo PaletteIndex
	for i = 0 to 15
		UpperRed = (AGAPalRed(i) LSR 4) LSL 8
		UpperGreen = (AGAPalGreen(i) LSR 4) LSL 4
		UpperBlue = (AGAPalBlue(i) LSR 4)

		LowerRed = (AGAPalRed(i) & $f) LSL 8
		LowerGreen = (AGAPalGreen(i) & $f) LSL 4
		LowerBlue = (AGAPalBlue(i) & $f)

		*SP\UpperRGB[i] = UpperRed | UpperGreen | UpperBlue
		*SP\LowerRGB[i] = LowerRed | LowerGreen | LowerBlue		
	next
End Statement

Statement UseSpritePalette{*SP.SpritePalette,CopperList}

	*cl.coplist = Addr CopList(CopperList)
	offset.l = *cl\colors + 270
	for i = 0 to 15
		Poke.w offset.l, *SP\UpperRGB[i]
		Poke.w offset.l+132, *SP\LowerRGB[i]
		offset + 4
	next

End Statement