What the bloody heck is wrong with this blitter routine?

[mcgeezer]

I've been debugging this blitter routine for over an hour, I can't spot what is wrong with it.... it'r probably something stupid but I'm quite tired.

I created the same routine using the CPU and it works no problem so it is something to do with my calculations or setting up the blitter somewhere.

VERTSCROLL_RESTORE:

	moveq	#0,d2
	move.w	#VERTICAL_WAIT_MAX,d2
	sub.w	VIDEO_SPLIT_LAST_POSY,d2
	move.w	d2,VERTCOPY_LINES_TOP	
	move.w	VIDEO_SPLIT_LAST_POSY,VERTCOPY_LINES_BOTTOM
	
	move.l	LSTPTR_POST_SCREEN,a0		; Screen location
	move.l	LSTPTR_CURRENT_SCREEN,a1		; Screen location

	moveq	#0,d0
	add.w	MAP_POSX,d0

	add.l	d0,a0		
	add.l	d0,a1
	
	move.l	a0,DEBUG_BLIT_POST
	move.l	a1,DEBUG_BLIT_CURRENT
	
	move.l	a0,d6
	move.l	a1,d7
;
; Copy from POST (0,VSPLIT_POSY) to CURRENT(0)

	lea	CANVAS_TABLE_Y3,a2
	moveq	#0,d2
	move.w	VIDEO_SPLIT_LAST_POSY,d2	; Get Vsplit Y Position
	add.l	(a2,d2.w*4),a0			; Index into POST screen.
; a0 now has start of copy.	
	
	moveq	#0,d0
	move.w	VERTCOPY_LINES_TOP,d0
	bmi.s	.skip_top
	beq.s	.skip_top
	
	IFEQ	VERT_USEBLITTER
	mulu	#50,d0			; 50 long words
.copy1:	move.l	(a0)+,(a1)+
	dbf	d0,.copy1
	ELSE		
	lsl.w	#6,d0
	add.w	#(20*5),d0
	WAIT_FOR_BLITTER
	move.l	#$09f00000,BLTCON0(a5)	; Select straigt A-D mode $f0
	move.l	#-1,BLTAFWM(a5)  	; No masking needed
	move.w	#0,BLTAMOD(a5)		; Playfield Modulo Src
	move.w	#0,BLTDMOD(a5)		; Playfield Modulo Dest
	move.l	a0,BLTAPTH(a5)		; set source address
	move.l	a1,BLTDPTH(a5)		; set dest address to back screen
	move.w	d0,BLTSIZE(a5)		; boom.....	
	ENDC	

.skip_top
	move.l	d6,a0
	move.l	d7,a1

	moveq	#0,d2
	move.w	VERTCOPY_LINES_TOP,d2
	add.l	(a2,d2.w*4),a1		; Index into Verical Top Lines into Destination.			
	
	moveq	#0,d0
	move.w	VIDEO_SPLIT_LAST_POSY,d0
	bmi	.fb
	beq	.fb

	IFEQ	VERT_USEBLITTER
	mulu	#50,d0			; 50 long words
.copy2:	move.l	(a0)+,(a1)+
	dbf	d0,.copy2
	ELSE
	lsl.w	#6,d0	
	add.w	#(20*5),d0			; d0 has blit size (100 words)
					; a0 has source
					; a1 has dest
					
	WAIT_FOR_BLITTER
	move.l	#$09f00000,BLTCON0(a5)	; Select straigt A-D mode $f0
	move.l	#-1,BLTAFWM(a5)  	; No masking needed
	move.w	#0,BLTAMOD(a5)		; Playfield Modulo Src
	move.w	#0,BLTDMOD(a5)		; Playfield Modulo Dest
	move.l	a0,BLTAPTH(a5)		; set source address
	move.l	a1,BLTDPTH(a5)		; set dest address to back screen
	move.w	d0,BLTSIZE(a5)		; boom.....	
	ENDC
.fb:	

.exit:
	rts

I just want to block copy 100 words wide by the height in d0 from one segment of memory to another. Bloody frustrating! The condition for VERT_USEBLITTER obviously either switches it from CPU to Blitter. a5 is pointing to $DFF000.

I'll probably post this and then immediately spot the problem - that's what normally happens.

[Toni Wilen]

Blitter width is only 6 bits (max 64 words).

[mcgeezer]

Originally Posted by Toni Wilen

Blitter width is only 6 bits (max 64 words).

If I had a slap in my face emoji I would use it.

Thanks Toni

[ross]

Don't be afraid to use BLTSIZV/H. You are on AGA

[mcgeezer]

Originally Posted by ross

Don't be afraid to use BLTSIZV/H. You are on AGA

You know what i knew there was a reason i was trying to blit that much and remembered it was possible! Cheers Ross!

[hooverphonique]

Originally Posted by ross

Don't be afraid to use BLTSIZV/H. You are on AGA

that works on ECS too, btw :-)

[meynaf]

If he is on AGA then there is 68020+ in the machine and it might be better to use the cpu rather than the blitter.