Virocop AGA - Harddisk install

[StingRay]

Originally Posted by ross

Well, using .w and the sign bit for accessMode is a great combo!
Bugs squared

For the bit of extra fun we all love.


I have updated the patch a bit, it should now run stable and also checks if it is already installed so running it twice is no problem (error code 10 is returned in that case).

; ViroCop Patch
; 
; patches Open() (dos.library) to accept accessMode as .w parameter
; this fixes the "Insert Disk 1" problem


START    move.l    $4.w,a6
    moveq    #0,d0            ; any version will do
    lea    DOSName(pc),a1
    jsr    -408(a6)        ; OpenLibrary()
    move.l    d0,a4
    tst.l    d0
    beq.b    .error

; patch Open() if patch is not installed
    lea    -30(a4),a0
    move.l    2(a0),a0
    cmp.l    #"STR!",2(a0)
    beq.b    .installed        ; patch is already installed

; allocate memory for patch code
    moveq    #Size,d0
    moveq    #0,d1            ; any memory will do
    jsr    -198(a6)        ; AllocMem()
    tst.l    d0
    beq.b    .error

    move.l    d0,a2

    moveq    #Size/2-1,d7
    move.l    d0,a1
    lea    NewOpen(pc),a0
.copy    move.w    (a0)+,(a1)+
    dbf    d7,.copy



    jsr    -132(a6)        ; Forbid()

    lea    -30.w,a0        ; Open()
    move.l    a4,a1            ; DOSBase
    move.l    a2,d0
    jsr    -420(a6)        ; SetFunction()
    move.l    d0,OldOpen-NewOpen(a2)

    jsr    -138(a6)        ; Permit()

.exit    moveq    #0,d0            ; no errors
    rts

.installed
    moveq    #10,d0            ; patch is already installed
    rts

.error    moveq    #20,d0            ; patch not installed
    rts



NewOpen    bra.b    .go
    dc.l    "STR!"
.go    swap    d2
    clr.w    d2
    swap    d2
    move.l    OldOpen(pc),-(a7)
    rts

OldOpen    dc.l    0

Size    = *-NewOpen

    dc.b    "$VER: Virocop patch 1.1 (21.03.2018) by StingRay/[S]carab^Scoopex",10,0
DOSName    dc.b    "dos.library",0

[dlfrsilver]

Thank you boys !

[Seiya]

now it works!!
Thanks...

[StingRay]

Have fun. I'm almost tempted to create a "real" fix for this game, I'll see if I can be bothered (game is pretty good so it sure is worth it).

[Seiya]

Hired Guns i have solved using ipf, but cracked version is the same. after regolar installation i have red screeen and floppy drive that search floppy disk..

[AMIGASYSTEM]

Originally Posted by Seiya

but don't work.

Assign ViroCop: ""
Assign ViroData1: ""
Assign ViroData2: ""
Askboot
Run >NIL: ViroCopPatch
ViroCopPal

[Seiya]

Originally Posted by AMIGASYSTEM

Run >NIL: ViroCopPatch
ViroCopPal

the first patch don't work. The latest one works perfectly

[AMIGASYSTEM]

Yes, even the first one works even if sometimes it fails.

Thanks to StingRay

[StingRay]

Yeah, the output redirection to >NIL: is a good hint!

[Seiya]

but in my case, the first patch you released, i have failure on every commands and then crash the system with guru

[jotd]

don't run the patch in background. or you can have a race condition between the game & the patch. Well, that's theory. no need to run in background anyway.

[Seiya]

however, now all works greatly

[StingRay]

The first version can indeed crash (coded before my first coffee, never a good idea) hence I updated the code and created a more stable version of the patch.

[Seiya]

and you have made a great fix