Show your startup-sequence file!

[bladecgn]

This is mine for OS 3.9 on WinUAE. Quite fast bootup, a lot faster than with the original startup-sequence.

I included some comments for better understanding.

; $VER: Startup-Sequence_HardDrive 45.1 (25.11.00)
; Startup-Sequence for hard drive systems

Resident >NIL: C:AddBuffers PURE
AddBuffers dh0: 200 >NIL:
AddBuffers dh1: 300 >NIL:
AddBuffers dh2: 350 >NIL:
Resident >NIL: C:Assign PURE
Resident >NIL: C:Execute PURE

c:uae-configuration cycle_exact FALSE cpu_speed max cachesize 8192 >NIL:

c:PatchControl
C:SetPatch NOROMUPDATE QUIET

set echo off
set _pchar "|"
set _mchar "||"

;run <nil: >NIL: hd:tools/snoopdos/snoopdos SETTINGS="s:safe_snoopdos.prefs"

;=== Patches ===
SYS:c2/StackAttack_020
SYS:c2/fblit >NIL:                           ;before MCP and other graphics patches
run <nil: >NIL: sys:c2/SysPatch NoGraphics -DoIo -WaitIo -AllocSignal -FreeSignal
SYS:c2/TagLIFE

;BEGIN HDEnv ; before LoadMonDrvs and MCP
 Assign >NIL: ENV: SYS:hdenv
 c:MakeDir ram:T
 Assign T: ram:T
 SYS:c2/HDEnv
;END HDEnv

c:AddDataTypes REFRESH QUIET                 ;before MCP

;sys:c2/MCPAssigns          
c:MCP NOLMB

C:Mount >NIL: DEVS:DOSDrivers/~(#?.info)

C:LoadMonDrvs

SetEnv Language "deutsch"
SetEnv Workbench $Workbench
SetEnv Kickstart $Kickstart
UnSet Workbench
UnSet Kickstart

C:IPrefs
SYS:c2/FPPrefs                               ;FullPalette
C:ConClip

Path >NIL: RAM: C: SYS:c2 SYS:Utilities SYS:Rexxc SYS:System S: SYS:Prefs SYS:WBStartup SYS:Tools SYS:Tools/Commodities

SYS:System/REXXMast >NIL:

SYS:C/MakeLink RAM:disk.info ENVARC:SYS/def_RAM.info SOFT

;IF EXISTS S:User-Startup
  Execute S:User-Startup
;EndIF

c:LoadWB ; SIMPLEGELS ; DELAY ; -debug

;sys:c2/memtrailer 96 ; problem with ambermoon 

EndCLI >NIL:

And user-startup:

;Kingcon instead of CON: and RAW:
Assign CON: DISMOUNT
Assign RAW: DISMOUNT
c:Mount CON: from DEVS:KingCon-mountlist
c:Mount RAW: from DEVS:KingCon-mountlist

;BEGIN SYSTEMPATCH
SYS:c2/SystemPatch NoUtil -LoadSeg DYNAMICDMA Q   ;-LoadSeg due to xvs.libray / virusz. NoUtil due to TagLife
;END SYSTEMPATCH

Path HD:Tools HD:PrgTools HD:DiskTools HD:Graphics HD:Graphics/Bin HD:Sound SSLROOT: ADD

run <>nil: sys:c2/MuiWheelPatch

All Assigns are done with MCP's Assign management.

I use a custom made (with Remus) 3.9 ROM.

[daxb]

First, somewhere in this thread there is the talk about PatchControl that with it patches can installed (s-s) in any order. Like SaferPatches you can install/remove patches in any order but it doesn`t know the patch itself. So you have to make sure that patches in s-s are in the right order. PatchControl/SaverPatches can`t do it for you.

Second, about tracking s-s/u-s. TCD? has shown the evil echo way. The most may know "set echo on". The last weeks I`ve tested "qboot" (aminet) what can monitor/log in a very good way. Good for debuging s-s/u-s.


Here my OS3.1 s-s/u-s (still in work since years). I`ve removed the most comments and unused stuff for better readability. Most assigns are made by MCP. Nothing special.

                             ; $VER: Startup-Sequence_HardDrive (08.11.2013) by BlakKhar
;S:qboot **
;Alias ss "Run Tools:Text/Jano_v1.01/JanoEditor s:qboot.conf s:startup-sequence"

C:RemAPollo KICKFILE Kickstart_romfixes2.rom MAC QUIET MODULES L:KingCON-handler L:SmartFilesystem DEVS:Modules/noclick

C:ATA3.driver QUIET

IF EXISTS Tools:Dev/Scripte/ActivateDrives.script
  Execute Tools:Dev/Scripte/ActivateDrives.script <>NIL:
ENDIF
IF EXISTS S:Startup-Sequence-keys
  Execute S:Startup-Sequence-keys
ENDIF

C:SetPatch QUIET
C:MuDRAP                     ; Apollo Remapper Deallocator for use with 68040/060.library from mmu.library package

Assign ENV: ENVARC:
C:StartupControl_V1.3 -r
Assign ENV: Remove

C:SaferPatches INSTALL REMEMBER WARN >NIL:
C:StackAttack_020
C:SegTracker FULLPATH
C:FastIEEE
C:Execute Tools:Dev/Scripte/DebugScript    ; Runs MuForce, Sashimi and NOT MuGuardianAngel
Run >NIL: CopyMem040

FailAt 21
C:Assign >NIL: ENV: NIL: PATH              ; Edit for AmberRAM
C:Assign >NIL: RAM: DISMOUNT               ; ...
C:Mount >NIL: "SYS:Storage/DOSDrivers/RAM" ; ...
C:Assign >NIL: ENV: REMOVE                 ; End of edit for AmberRAM

C:env-handler ADDVOLNODE VOLNAME=DaxB
C:MakeDir RAM:T RAM:Clipboards
Assign >NIL: T: RAM:T
Assign >NIL: CLIPS: RAM:Clipboards

C:LoadMonDrvs
C:FBlit
C:SystemPatch NL ND -ObtainBestPenA -RawDoFmt -TLSF -CopyMems QUIET
C:MCP
C:Mount >NIL: DEVS:DOSDrivers/~(#?.info)
C:AddDataTypes REFRESH
C:Run >NIL: C:VisualPrefs
C:FastIPrefs W F O
C:ConClip
SYS:Prefs/FPPrefs

Path >NIL: RAM: C: SYS:Utilities SYS:Rexxc SYS:System S: SYS:Prefs SYS:WBStartup SYS:Tools SYS:Tools/Commodities DOpus5:c Tools:Text/CygnusEd Add

IF EXISTS S:User-Startup
  Execute S:User-Startup
ENDIF

C:StackAttack_020 AUTO
C:LoadDB                     ; Directory Opus Magellan II
ENDCLI >NIL:

User-Startup:

;BEGIN MUI
IF EXISTS "MUI:AUS"         ; This line deactivates the MUI assigns below. :-)
if exists "Tools:System/MUI"
   assign MUI: "Tools:System/MUI"
   if exists MUI:Libs
      assign add LIBS: MUI:Libs
   endif
   if exists MUI:Locale
      assign add LOCALE: MUI:Locale
   endif
   version >nil: exec.library 39
   if not warn
      if exists MUI:Docs
         if exists HELP:dummy ; do not remove
         endif                ; this entry!
         assign add HELP: MUI:Docs
      endif
   endif
endif
ENDIF

Run <NIL: >NIL: C:NewIcons
C:MIPrefs
SYS:System/RexxMast >NIL:
C:BootCounter
C:xxx RENRAM MOUNTSIZE=6880  ; Safe

; This mounts KCON and KRAW
Assign CON: DISMOUNT
Assign RAW: DISMOUNT
Mount CON: from DEVS:KingCON-mountlist
Mount RAW: from DEVS:KingCON-mountlist
;Mount KCON: from DEVS:KingCON-mountlist
;Mount KRAW: from DEVS:KingCON-mountlist

Run >NIL: XpkMasterPrefs

xfdPatch >NIL:

Path Tools:Gfx/Viewer/SView5/ ADD
;Assign VMEM: Temp:

version C:MCP >ENV:MCPVer
version SYS:Prefs/MCPPrefs >ENV:MCPPrefsVer
version DOpus5:DirectoryOpus >ENV:DOpusVer
version DH0: >ENV:Filesystem
version icon.library >ENV:IconVer
rx "IF ~OPEN('newStr','ENV:IconVerNew','WRITE') THEN EXIT;IF OPEN('verStr','ENV:IconVer','READ') THEN WRITECH('newStr',RIGHT(READLN('verStr'),4))"

version C:ATA3.driver full >ENV:Signature
version DH0: >>ENV:Signature
version DH4: >>ENV:Signature
version C:RemAPollo >>ENV:Signature
echo "" >>ENV:Signature
echo "Patches:" >>ENV:Signature
version Tools:System/Remus/others/Blizkick/romfixes2 full >>ENV:Signature
version C:SaferPatches >>ENV:Signature
version C:SegTracker >>ENV:Signature
version C:CopyMem040 >>ENV:Signature
version C:StackAttack_020 >>ENV:Signature
version C:FastIEEE >>ENV:Signature
version C:env-handler >>ENV:Signature
version C:LoadMonDrvs >>ENV:Signature
version C:FBlit >>ENV:Signature
version C:SystemPatch >>ENV:Signature
version C:MCP >>ENV:Signature
version C:VisualPrefs >>ENV:Signature
version C:FastIPrefs full >>ENV:Signature
version DOpus5:DirectoryOpus full >>ENV:Signature
version C:XpkMasterPrefs >>ENV:Signature
version C:xfdPatch >>ENV:Signature
version SYS:WBStartup/MagicMenu >>ENV:Signature

[Nobby_UK]

Almost Original :

; $VER: startup-sequence 39.9 (9.8.92)
C:SetPatch QUIET
FailAt 21
C:CardPatch
C:CardReset

; Added by NETPCM010 Installer
IF EXISTS C:Execute-Wireless-Startup
    C:Execute-Wireless-Startup
ENDIF

C:Version >NIL:
;C:AWS -p0 -a -h12 -k0
C:AddBuffers >NIL: DF0: 15

C:MakeDir RAM:T RAM:Clipboards RAM:ENV RAM:ENV/Sys
C:Copy >NIL: ENVARC: RAM:ENV ALL NOREQ

Resident >NIL: C:Assign PURE
Resident >NIL: C:Execute PURE

Assign >NIL: ENV: RAM:ENV
Assign >NIL: T: RAM:T
Assign >NIL: CLIPS: RAM:Clipboards
Assign >NIL: REXX: S:
Assign >NIL: PRINTERS: DEVS:Printers
Assign >NIL: KEYMAPS: DEVS:Keymaps
Assign >NIL: LOCALE: SYS:Locale
Assign >NIL: LIBS: SYS:Classes ADD
Assign >NIL: HELP: LOCALE:Help DEFER
Assign Miami: Sys:Miami DEFER

IF NOT EXISTS SYS:Fonts
  Assign FONTS:
EndIF

BindDrivers
C:Mount >NIL: DEVS:DOSDrivers/~(#?.info)
C:MOUNT NEWCON:

IF EXISTS DEVS:Monitors
  IF EXISTS DEVS:Monitors/VGAOnly
    DEVS:Monitors/VGAOnly
  EndIF

  C:List >NIL: DEVS:Monitors/~(#?.info|VGAOnly) TO T:M LFORMAT "DEVS:Monitors/%s"
  Execute T:M
  C:Delete >NIL: T:M
EndIF

SetEnv Workbench $Workbench
SetEnv Kickstart $Kickstart
UnSet Workbench
UnSet Kickstart

C:FastIPrefs F
C:ConClip

Path >NIL: RAM: C: SYS:Utilities SYS:Rexxc SYS:System S: SYS:Prefs SYS:WBStartup SYS:Tools SYS:Tools/Commodities

IF EXISTS S:User-Startup
  Execute S:User-Startup
EndIF

Resident Execute REMOVE
Resident Assign REMOVE

C:LoadWB
;C:AWS -x
EndCLI >NIL:

User-StartUp

;BEGIN MUI
if exists "System:MUI"
   assign MUI: "System:MUI"
   if exists MUI:Libs
      assign add LIBS: MUI:Libs
   endif
   if exists MUI:Locale
      assign add LOCALE: MUI:Locale
   endif
   version >nil: exec.library 39
   if not warn
      if exists MUI:Docs
         if exists HELP:dummy ; do not remove
         endif                ; this entry!
         assign add HELP: MUI:Docs
      endif
   endif
endif
;END MUI

;C:PointerX
C:Copy >NIL: Sys:Storage/Ram-Disk.icon to RAM:Disk.info
;SYS:System/SetMap gb


;BEGIN Miami + Samba
;Assign MIAMI: "SYS:Miami"
Assign SAMBA: "MIAMI:SAMBA"
Path Samba:Bin  add
;END Miami + Samba

;BEGIN YAM - Amiga mailer © Marcel Beck
C:Assign YAM: "SYSTEM:YAM"
;END YAM - Amiga mailer © Marcel Beck


;BEGIN SiSys:  needs to be assigned for the various components to run
;assign sisys: Sys:SiSys
;path sisys: ADD
;END SiSys:  needs to be assigned for the various components to run

;BEGIN FTPMount
assign FTPMountDir: SYSTEM:FTPMountDir
;END FTPMount

;BEGIN NewIcons
Run <NIL: >NIL: c:NewIcons
;END NewIcons

;BEGIN DefIcons
;DefIcons
;END DefIcons

;BEGIN JPEG Codec
;Assign JPEGTMP: "WORK:"
;END JPEG Codec

;BEGIN Picasso96
;Assign Picasso96: "Work:Picasso96"
;END Picasso96

;BEGIN Mixer
;Path sys:prefs ADD
;Mixer NOGUI QUIET
;END Mixer

;BEGIN IOSPIRIT VHI Studio
;Assign VHIStudio: REMOVE
;Assign VHIStudio: "WORK:VHIStudio"
;END IOSPIRIT VHI Studio

;BEGIN TurboPrint
;Assign TurboPrint: "Work:TurboPrint"
;END TurboPrint

;BEGIN CacheCDFS
;END CacheCDFS
;BEGIN AmiTCP & EasyNet

Assign AmiTCP: "SYSTEM:AmiTCP"
path AmiTCP:bin add
;END AmiTCP & EasyNet

;BEGIN WirelessManager
Run <>NIL: C:WirelessManager prism2.device
;END WirelessManager

[Nibbler]

This is for my Amiga 600 Furia V2.
-------------------------------------------------------------------
C:Stack 8192
C:Furiatune ShadowRom AddMem >Nil:
C:Setpatch NoNSD NoRomUpdate Quiet
C:Syspic SYS:BootPic/Fashion So BB
C:MakeDir RAM:T RAM:Clipboards
Resident >NIL: C:Assign PURE
Assign >NIL: ENV: ENVARC:
Assign >NIL: T: RAM:T
Assign >NIL: CLIPS: RAM:Clipboards
Assign >NIL: REXX: S:
Assign >NIL: PRINTERS: DEVS:Printers
Assign >NIL: KEYMAPS: DEVS:Keymaps
Assign >NIL: LOCALE: SYS:Locale
Assign >NIL: LIBS: SYS:Classes ADD
Assign >NIL: HELP: LOCALE:Help DEFER
C:FBlit
C:MCP
C:BindDrivers
C:Mount >NIL: DEVSOSDrivers/~(#?.info)
C:LoadMonDrvs
C:AddDataTypes REFRESH QUIET
C:IPrefs
C:ConClip
Path >NIL: RAM: C: SYS:Utilities SYS:Rexxc SYS:System S: SYS:Prefs SYS:WBStartup SYS:Tools SYS:Tools/Commodities
SYS:System/RexxMast >NIL:
Execute S:User-Startup
Resident Assign REMOVE >NIL:
C:LoadWB SimpleGels
C:Stripes 0 3 1 8 0 >Nil:
EndCLI >NIL:

------------------------------------------------

Take about 2 seconds

[daxb]

It's always a good ide to put "special" text in CODE tags or at least disable smilies if possible. This way it holds the format and is better readable. Try it.

[meynaf]

My own (very non-standard) startup-sequence. Boots in 1.5 secs under winuae

patchrom quiet
setpatch quiet
makedir ram:env ram:env/sys
assign env: ram:env
assign env: sys:prefs/config add
assign envarc: sys:prefs/p
assign envarc: sys:prefs/config add
assign s: sys:prefs/config
assign s: sys:s add
assign l: sys:prefs/config
assign l: sys:l add
assign t: ram:
assign clips: t:
assign keymaps: sys:prefs/p
assign libs: sys:classes add
assign locale: sys:locale
copy >nil: prefs/p/sys/#? env:sys
iprefs
conclip
path ram: sys:utils c:
loadwb
endcli

Where "patchrom" command is a program of mine that patches kickstart in B1230 memory (for e.g. access to >4GB hard drives). Don't search for it, it has never been released anywhere.
Note that as i just hate these programs putting their dirts in S: or L:, they will go elsewhere when writing (config files are kept together in same dir).

Multi-CX and any relevant monitor files all are in WBStartup.